The function f(x,y)=((x y)/((x^2)+(y^2))).

f[x_,y_]:=x*y/(x^2+y^2);
plot = Plot3D[f[x,y],{x,-1,1},{y,-1,1},Mesh->None,AxesOrigin->{0,0,0},Boxed->False]

xAxisApproach = ParametricPlot3D[{0,t,0},{t,-1,1},PlotStyle->{Blue,Thick}];
yAxisApproach = ParametricPlot3D[{t,0,0},{t,-1,1},PlotStyle->{Red,Thick}];
plusDiagonalApproach = ParametricPlot3D[{t,t,f[t,t]},{t,-1,1},PlotStyle->{Green,Thick}];
minusDiagonalApproach = ParametricPlot3D[{t,-t,f[t,-t]},{t,-1,1},PlotStyle->{Black,Thick}];

{Show[plot,xAxisApproach,yAxisApproach,plusDiagonalApproach,minusDiagonalApproach,ImageSize->350]
ContourPlot[f[x,y],{x,-1,1},{y,-1,1},Contours->20,ImageSize->300]}

The function f(x,y)=(((x^2)-(y^2))/((x^2)+(y^2))).  This is Example 8, page 103 of Colley.

f[x_,y_]:=(x^2-y^2)/(x^2+y^2);
Plot3D[f[x,y],{x,-1,1},{y,-1,1},Mesh->None,AxesOrigin->{0,0,0},Boxed->False]
(* ContourPlot[f[x,y],{x,-1,1},{y,-1,1},Contours->20] *)

The function f(x,y)=(((x^4)(y^4))/((((x^2)+(y^4)))^3)).

f[x_,y_]:=(x^4*y^4)/(x^2+y^4)^3;
{newPLot = Plot3D[f[x,y],{x,-1,1},{y,-1,1},Mesh->None,AxesOrigin->{0,0,0},Boxed->False,BoxRatios->{1,1,.5},ImageSize->350],
ContourPlot[f[x,y],{x,-1,1},{y,-1,1},Contours->20,ImageSize->300] }
xAxisApproach = ParametricPlot3D[{0,t,0},{t,-1,1},PlotStyle->{Blue,Thick}];
yAxisApproach = ParametricPlot3D[{t,0,0},{t,-1,1},PlotStyle->{Red,Thick}];
plusDiagonalApproach = ParametricPlot3D[{t,t,f[t,t]},{t,-1,1},PlotStyle->{Green,Thick}];
slantApproach[c_]:= ParametricPlot3D[{t,c*t,f[t,c*t]},{t,-1,1},PlotStyle->{Green,Thick}];
quadApproach = ParametricPlot3D[{t^2,t,f[t^2,t]},{t,-1,1},PlotStyle->{Black,Thick}];
Manipulate[Show[newPLot,xAxisApproach,yAxisApproach,slantApproach[c],quadApproach,ImageSize->350],{c,-5,5}]

Expand[f[t,c*t]]
Expand[(t^2+c^4t^4)^3]

Limit[f[t,c*t],t->0]

The function g(x,y)=(x^2)+(y^2).

g[x_,y_]:=(x^2+y^2);
{Show[Plot3D[g[x,y],{x,-4,4},{y,-4,4},Mesh->None,BoxRatios->Automatic,RegionFunction->Function[{x,y,z},x^2+y^2≤8],ImageSize->350]],
ContourPlot[g[x,y],{x,-4,4},{y,-4,4},Contours->20,ImageSize->300]}

The function h(x,y)=2(x^2)-(y^2).

h[x_,y_]:=2*x^2-y^2;
{Show[Plot3D[h[x,y],{x,-2,2},{y,-2,2},Mesh->None,ImageSize->350]],
ContourPlot[h[x,y],{x,-2,2},{y,-2,2},ImageSize->300]}

The function  k(x,y)=(1/12)(y^3)-y-(1/4)(x^2)+(7/2).

k[x_,y_]:=1/12*y^3-y-.25*x^2+7/2;{Manipulate[Plot3D[Max[k[x,y],t] ,{x,-6,6},{y,-6,4},Mesh->None,PlotRange->{{-6,6},{-6,4},{0,6}}],{{t,0,"Floor"},0,4}],
Show[ContourPlot[k[x,y],{x,-6,6},{y,-6,4},Contours->30],Plot[0,{x,-6,6}],ParametricPlot[{0,t},{t,-6,6}],Graphics[{PointSize[Large],Point[{0,2}]}],Graphics[{PointSize[Large],Point[{0,-2}]}],ImageSize->300]}