The function f:ℝ⟶(ℝ^2), f(t)=(x(t),y(t))=(cos t, sin t).  We graph this both as a subset of three-apace and as a parameterized curve in (ℝ^2).

(* Graph of f in real three space with coordinates (t,x,y) from t=0 to t= the input t0. PLace a dot at the end. *)
	coil[t0_]:=ParametricPlot3D[{t,Cos[t],Sin[t]},{t,0,t0},PlotStyle->{Red,Thick},AxesOrigin->{0,0,0},Boxed->False,ImageSize->450, PlotRange->{{0,20},{-1.2,1.2},{-1.2,1.2}}];
	dot3D[t0_]:=Graphics3D[{PointSize[Large],Blue,Point[{t0,Cos[t0],Sin[t0]}]}]

(* Graph of f as a parateterized curve in the plane with coordinates (x,y), from t=0 to t= the input t0. PLace a dot at the end. *)
	dot2D[t0_]:=Graphics[{PointSize[Large],Blue,Point[{Cos[t0],Sin[t0]}]}]
	circle[t0_]:=ParametricPlot[{Cos[t],Sin[t]},{t,0,t0},PlotStyle->{Red,Thick},PlotRange->{{-1.2,1.2},{-1.2,1.2}}];

(* Show both graphs side-by-side in way that the user can vary the ednpoint of the input domain.  *)
	Manipulate[{Show[coil[t],dot3D[t]],Show[circle[t],dot2D[t]]}, {t,0.01,20}]

The curve f:ℝ⟶(ℝ^2), f(t)=(x(t),y(t))=(sin t ,(sin^2)t).  Notice that the curve may be  differentiable as a function even if the actual curve has a corner.  Why is this so?  How is this so?

(* The curve parameterized by t, given by f, from t=0 to t=4Pi.  *)
	x1[t_]:=Sin[t];
	y1[t_]:=(Sin[t])^2;
	tMin = 0;
	tMax = 4*Pi;

(* Show it all in a way that the user can manipulate the end point of the input domain (the parameter). *)
	Manipulate[Show[ParametricPlot[{x1[a],y1[a]},{a,0,t + .001},PlotRange->{{-1.5,1.5},{-.5,1.5}}],Graphics[{PointSize[Large],Red,Point[{Sin[t],(Sin[t])^2}]}]],{t,tMin,tMax}]

The curve f:ℝ⟶(ℝ^2), f(t)=(x(t),y(t))=(t-sin t,1-cos t) is called the cycloid.  Notice that the curve may be  differentiable as a function even if the actual curve has a corner.  Why is this so?  How is this so?

(* The parameterized cycloid functions, from t=1 to t=tMax. *)
	x2[t_]:=t-Sin[t];
	y2[t_]:=1-Cos[t];
	tMin = 0;
	tMax = 7*Pi;

(* The graph of the cycloid, with a dot at the endpoint.  *)
	cycloid[t0_]:=ParametricPlot[{x2[t],y2[t]},{t,0,t0 + .001},PlotRange->{{-.5,20},{-.5,2.5}},ImageSize->500]
	cdot[t0_]:=Graphics[{PointSize[Large],Blue,Point[{t0-Sin[t0],1-Cos[t0]}]}]

(* A superimposed rolling circle to show how the cycloid is formed. *)
	ccircle[t0_]:=Graphics[{Red,Circle[{t0,1}]}]

(* Show it all as a quick video. *)
	Manipulate[Show[cycloid[t],cdot[t],ccircle[t]],{t,tMin,tMax}]