An example of two vectors determining a plane

Define two vectors v1 and v2;  Change these if you like.  The syntax here is that these vectors are represented by the points at their respective  heads.  It is understood that their tail is at the origin.  To graph such a thing as a vector, Mathematica uses the graphics Arrow[{{0, 0, 0}, v1}].

v1={1,1,1}; 
v2={1,1,-1};

Graph them in 3 - space.  Once you see the graph, you can rotate the graph around using your mouse,  This helps to get a better idea of how the vectors are sitting relative to each other and the axes.

s=Max[Max[Abs[v1]],Max[Abs[v2]]];scale = {-(s+1),s+1};Show[Graphics3D[{Thick,Red,Arrow[{{0,0,0},v1}]}],Graphics3D[{Thick,Red,Arrow[{{0,0,0},v2}]}],PlotRange->{scale,scale,scale},Axes->True,AxesOrigin->{0,0,0},Boxed->False]

The cross product of v1 and v2, call it v3, gives us the coefficients of the Planar Equation which defines the plane that v1 and v2 live in.  This gives us a planar equation as v3(1) x +v3(2) y+v3(3) z = 0.  We can write this as z as a function of x and y, so that z = (3/2) x - (1/2) y;  We plot this below.  Note that I have written this code to account for the fact that the cross product vector v3 may have a z-component of 0.  IN that case, I have to be more careful how to graph.  Do not worry about this now.  But do rotate around the picture to see that both of the vectors are sitting in the plane.

v3 = Cross[v1,v2];
If[v3[[3]]≠ 0,plane = Plot3D[-(v3[[1]]/v3[[3]])x-(v3[[2]]/v3[[3]])y,{x,-s-10,s+10},{y,-s-10,s+10},Mesh->False,FillingStyle->Opacity[.25]],If[v3[[2]]≠0, plane = ParametricPlot3D[{t,-(v3[[1]]/v3[[2]])t,u},{t,-s-10,s+10},{u,-s-10,s+10},Mesh->False,PlotStyle->Opacity[.25]],plane = ParametricPlot3D[{0,t,u},{t,-s-10,s+10},{u,-s-10,s+10},Mesh->False,PlotStyle->Opacity[.25]]]];
Show[Graphics3D[{Thick,Red,Arrow[{{0,0,0},v1}]}],plane,Graphics3D[{Thick,Red,Arrow[{{0,0,0},v2}]}],PlotRange->{scale,scale,scale},Axes->True,AxesOrigin->{0,0,0},Boxed->False]

One can construct a plane in three space, passing through a point x0 = (a,b,c) by specifying a vector w = [w1,w2,w3]^T based at x0.  The equation for this plane is w1*(x-a) + w2*(y-b)+ w3*(z-c) = 0.  for any choice of nonzero w1 or w2 or w3, as can solve for one of x, y, or z, respectively, and then graph the plane as a function of the other variables.  For the choice of x0 = (1,1,1) below, the vector w = [1,2,3}^T determines the plane shown and given by the equation (x-1) + 2*(y-1) + 3*(z-1) = 0.  Below, we choose to graph this as the function z = 1/3*(- x - 2y + 6), or z = - (1/3)x - (2/3)y + 2.  Change the values of w and/or x0 to see how this changes the plane.  And use your mouse to move around the graph to better see the plane form other angles.

w = {1,2,3};
x0 = {1,1,1};
s=Max[Abs[v1]];scale = {-(s+1),s+1};
plane = Plot3D[-(w[[1]]/w[[3]])x-(w[[2]]/w[[3]])y+w.x0/w[[3]],{x,-s-10,s+10},{y,-s-10,s+10},Mesh->False,FillingStyle->Opacity[.25]];
Show[Graphics3D[{Thick,Red,Arrow[{x0,x0+w}]}],plane,PlotRange->{4*scale,4*scale,4*scale},Axes->True,AxesOrigin->{0,0,0},AxesLabel->{x,y,z},Boxed->False]