# Maintainer: Kyle Keen <keenerd@gmail.com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Jason Chu <jason@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>

pkgname=gforth
pkgver=0.7.3
pkgrel=2
url="http://www.gnu.org/software/gforth/"
pkgdesc="Fast and portable implementation of the ANS Forth language"
arch=('i686' 'x86_64' 'armv6h')
license=('GPL3')
depends=('libtool')
source=("http://www.complang.tuwien.ac.at/forth/$pkgname/$pkgname-$pkgver.tar.gz")
md5sums=('ff484391e5cdf405867fcf96341820ab')
options=('libtool')
install=$pkgname.install

build() {
    cd "$srcdir/$pkgname-$pkgver"
    ./autogen.sh
    CFLAGS='-std=gnu99' ./configure --prefix=/usr
    make -j $(nproc) PREFIX=/usr
    make -j $(nproc) PREFIX=/usr doc
    make -j $(nproc) PREFIX=/usr more
}

package() {
    cd "$srcdir/$pkgname-$pkgver"
    mkdir -p $pkgdir/usr/share/emacs/site-lisp/
    make PREFIX=/usr DESTDIR="$pkgdir" install
    rm $pkgdir/usr/share/emacs/site-lisp/gforth.elc
}